//media statements for the waterfall
//Kurt Bangert
//http://www.travelnotes.de/rays/  

#declare water_1 = 
      media {
     emission .5
     absorption .3
// the emission value is critical, especially 
// if you change the size, you have to adapt this value
      density {
       cylindrical
       turbulence <.5,.5,.5>  
       octaves 10  
       omega .9
       lambda 1.5
        color_map {
          [0.0 color rgb <0,0,0>]
          [0.4 color rgb <0,0,0>]
          [0.5 color rgb <.6,1,1>]
          [0.6 color rgb <0,0,0>]
          [0.9 color rgb <0,0,0>]
          [0.9 color rgb <1,1,1>]
          [1.0 color rgb <1,1,1>]
          } //end color map
          } //end density
           scale <.2,3,1>  
          } //end media            

#declare water_2 = 
      media {
     emission .3
      absorption 0.2
      density {
       gradient y
       turbulence <.5,.5,.5>  
       color_map {
          [0.0 color rgb <0,0,0>]
          [0.05 color rgb <0,0,0>]
          [0.1 color rgb <.7,1,1>]
          [1.0 color rgb <0,0,0>]
          } //end color map
          } //end density
          } //end media            

#declare water_3 = 
      media {
     emission .9
      absorption .8
      density {
      cylindrical
      turbulence <.5,.5,.5>  
      octaves 10  
       omega .9
      lambda 1.5
       color_map {
          [0.0 color rgb <0,0,0>]
          [0.05 color rgb <0,0,0>]
          [0.1 color rgb <.7,1,1>]
          [0.15 color rgb <.7,1,1>]
          [1.0 color rgb <0,0,0>]
          } //end color map
          } //end density
          } //end media    
          
#declare watertex_1=
  texture {
    pigment {
      gradient y
      color_map {
        [ 0.0   color White*.6 ]
        [ 0.2   color White]
        [ 0.3   color Blue*.6 ]
        [ 0.4   color White ] 
        [ 0.8   color White ]
        [ 1.00  color Blue*.6 ]}
      turbulence 1.5
            } finish { Luminous }
  }  
  
//a sky sphere. It is from POV-Ray skies.inc, 
//I just made the first pigment statement brighter
sky_sphere {
    pigment { rgb <0.5, 0.5, 1> }  //sky color
    pigment {
        bozo
        turbulence 1.5
        octaves 10
        omega .5
        lambda 2.5
        color_map {
            [0.0, 0.5 color rgbf<.75, .75, .75, 0>
                      color rgbf<.9, .9, .9, .9> ]
            [0.5, 0.7 color rgbf<.9, .9, .9, .9>
                      color rgbf<1, 1, 1, 1> ]
            [0.7, 1.0 color rgbf<1, 1, 1, 1>
                      color rgbf<1, 1, 1, 1> ]
        }
    scale <1, 0.3, 10>
    }
    pigment {
        bozo
        turbulence 0.6
        octaves 10
        omega .5
        lambda 2.5
        color_map {
            [0.0, 0.4 color rgbf<.75, .75, .75, 0>
                      color rgbf<.9, .9, .9, .9> ]
            [0.4, 0.7 color rgbf<.9, .9, .9, .9>
                      color rgbf<1, 1, 1, 1> ]
            [0.7, 1.0 color rgbf<1, 1, 1, 1>
                      color rgbf<1, 1, 1, 1> ]
        }
    scale <1, 0.3, 10>
    }
    pigment {
        bozo
        turbulence 0.8
        octaves 10
        omega .5
        lambda 2.5
        color_map {
            [0.0, 0.4 color rgbf<.75, .75, .75, 0>
                      color rgbf<.9, .9, .9, .9> ]
            [0.4, 0.6 color rgbf<.9, .9, .9, .9>
                      color rgbf<1, 1, 1, 1> ]
            [0.6, 1.0 color rgbf<1, 1, 1, 1>
                      color rgbf<1, 1, 1, 1> ]
        }
    scale <1, 0.3, 10>
    }
}