//a scene with a seaplane and palms
//by Kurt Bangert
//http://www.travelnotes.de/
#include "colors.inc" 
#include "textures.inc"
#include "finish.inc"
#include "metals.inc"
#include "b317.inc"  
#include "woods.inc"
#include "palms.inc" 

#declare LGreen=color rgb <.2,1,.2>
#declare YGreen=color rgb <.7,1,0>
  
#declare bushtex1 =
  texture {
    pigment {
      radial
      color_map {
        [ 0.0 color DarkGreen*.7 ]
        [ 0.1     color DarkGreen] 
        [ 0.4 color DarkGreen*1.2] 
        [ 0.6        color Brown ]
         [ 0.8        color Green ]
        [ 1.00       color Green ]}
      turbulence 1  octaves 6  omega 8 }}
 
#declare skyblue = pigment{
        gradient y
        color_map {
          [0.0 color rgb <.5, .5, 1>]
          [0.3 color rgb <0.3, 0, 0.7>]  
          [1.0 color rgb <0.1, 0, .5>]
        } scale 10000 }

camera {location <0,2,-35>
angle 46
look_at <-2,2,0>} 

object{sphere{<0,0,0> 10000} hollow texture {pigment {skyblue} finish {Luminous}}}

light_source { < 200,10,-300> color rgb <1,.8,1> }

object {height_field { tga "waves.tga" smooth scale <50,.12,50> translate<-25,1.1,-50> }
 normal {bumps 0.2 scale 0.5}
 pigment {Gray30} finish {ambient 0.1 diffuse 0.2 reflection 0.7}}

//mountain

#declare mountain = object {height_field { tga "mountain.tga" }}
object {mountain scale <1000,800,1000> translate<-100,0,-10> texture{bushtex1}}
//clouds
object {mountain 
        texture {pigment{
        gradient y
        color_map {
          [0.0 color rgbt <1, 1, 1, 1>]    
          [0.5 color rgbt <1, 1, 1,0.5>]    
          [1.0 color rgbt <1, 1, 1, 0>]
        }} finish {Luminous}scale 0.3} 
           rotate -x*90 scale <800,200,100> 
           translate<-400,50,500> }

object{seaplane
rotate y*215 
translate <-2.5,2.4,-20>}
 
#declare boardwalk=union{
//lower level
object{box{<3,1.4,-.1><.1,1.5,-50>} }
object{box{<-.1,1.4,-30><-20,1.5,-20>}}  
object{box{<2.5,1.6,-.1><.1,1.7,-.2>}}    
object{box{<.1,1.6,0><.2,1.7,-20>}}  

#declare i=.5; 
 #while (i<3) 
  object {box {<i,-3,0> <i-.1,1.75,-.1>} }
 #declare i=i+.5;
 #end              
 #declare i=0; 
 #while (i>-20) 
  object {box {<0,-3,i> <.1,1.75,i+.1>} }
 #declare i=i-1;
 #end  
}

object{boardwalk texture {T_Wood3}
rotate y*215 
translate <3,0,-19>
}                

//a loop to declare a forest with 40 palm trees
#declare r1 = seed(1);                     
 #declare i=1;
  #while (i<40)  
   #declare position=<-3*i+60,-rand(r1)*4+21,rand(r1)*40+20>;  
    //start of a single palm tree
    palmtree(position)
  #declare i=i+1;
  #end