//POV-RAy source for a simple waterfall
//by Kurt Bangert
//http://www.travelnotes.de/rays/
//use Antialiasing 

#include "colors.inc"
#include "textures.inc"
 
//light_source and camera
 
light_source { <30, 50, -20> color rgb<1.2,1.2,1.2> }
 
camera {location <0,28,-60>
look_at <0,25,0>}

sphere {<0,0,0>1000 hollow pigment {CornflowerBlue} finish {Luminous}}

//a simple background for the waterfall
object {box {<-50,-1,-50><50,0,50> pigment {Gray40}}}
difference{
object {box {<-50,0,0><50,50,1> pigment {Gray40}}}
object {box {<-3,0,-10><3,6,10> 
 rotate z*45 translate <1.7,48,0> pigment {Gray40}}}
}
                                       
//a single media statement for the waterfall
#declare falling_water = 
      media {
      emission 2.5 
// the emission value is critical, especially 
// if you change the size, you have to adapt this value
      density {
       cylindrical
       turbulence <1,1,1>  
       octaves 10  
       omega .9
       lambda 1.5
        color_map {
          [0.0 color rgb <0,0,0>]
          [0.4 color rgb <0,0,0>]
          [0.5 color rgb <.6,1,1>]
          [0.6 color rgb <0,0,0>]
          [0.9 color rgb <0,0,0>]
          [0.9 color rgb <1,1,1>]
          [1.0 color rgb <1,1,1>]
          } //end color map
          } //end density
           scale <.2,3,1>  
          } //end media            
          
          
//the waterfall is a transparent sphere scaled to a long ellipsoid
//and filled with the media "falling_water"

object{sphere { <0,0,0> 1 scale <1,10,1> 
         pigment {color rgbt<1, 1, 1, .99>} 
         interior {media {falling_water}}
       hollow} scale 4.8 }